Library mcertikos.devdrivers.HandlerCxtGen


This file provide the contextual refinement proof between MALInit layer and MALOp layer
Require Import Coqlib.
Require Import Errors.
Require Import AST.
Require Import Integers.
Require Import Floats.
Require Import Op.
Require Import Asm.
Require Import Events.
Require Import Globalenvs.
Require Import Smallstep.
Require Import Values.
Require Import Memory.
Require Import Maps.
Require Import CommonTactic.
Require Import AuxLemma.
Require Import FlatMemory.
Require Import AuxStateDataType.
Require Import Constant.
Require Import GlobIdent.
Require Import RealParams.
Require Import LoadStoreSem1.
Require Import AsmImplLemma.
Require Import LAsm.
Require Import RefinementTactic.
Require Import DevicePrimSemantics.

Require Import liblayers.logic.PTreeModules.
Require Import liblayers.logic.LayerLogicImpl.
Require Import liblayers.compcertx.Stencil.
Require Import liblayers.compcertx.MakeProgram.
Require Import liblayers.compat.CompatLayers.
Require Import liblayers.compat.CompatGenSem.
Require Import compcert.cfrontend.Ctypes.
Require Import LayerCalculusLemma.

Require Import AbstractDataType.
Require Import DeviceStateDataType.
Require Import DHandlerCxt.
Require Import LAsmModuleSem.
Require Import I64Layer.
Require Import ObjX86Proof.

Notation of the refinement relation

Section Refinement.

  Local Open Scope string_scope.
  Local Open Scope error_monad_scope.
  Local Open Scope Z_scope.

  Context `{real_params: RealParams}.
  Context `{oracle_prop: MultiOracleProp}.

  Notation HDATA := RData.
  Notation LDATA := RData.

  Notation HDATAOps := (cdata (cdata_ops := dhandlerintro_data_ops) HDATA).
  Notation LDATAOps := (cdata (cdata_ops := dhandlerintro_data_ops) LDATA).

  Section WITHMEM.

    Context `{Hstencil: Stencil}.
    Context `{Hmem: Mem.MemoryModelX}.
    Context `{Hmwd: UseMemWithData mem}.

Definition the refinement relation: relate_RData + match_RData

    Record relate_RData (f:meminj) (hadt: HDATA) (ladt: LDATA) :=
      mkrelate_RData {
          flatmem_re: FlatMem.flatmem_inj (HP hadt) (HP ladt);
          MM_re: MM hadt = MM ladt;
          MMSize_re: MMSize hadt = MMSize ladt;
          vmxinfo_re: vmxinfo hadt = vmxinfo ladt;
          CR3_re: CR3 hadt = CR3 ladt;
          ikern_re: ikern hadt = ikern ladt;
          pg_re: pg hadt = pg ladt;
          ihost_re: ihost hadt = ihost ladt;
          AC_re: AC hadt = AC ladt;
          ti_fst_re: (fst (ti hadt)) = (fst (ti ladt));
          ti_snd_re: val_inject f (snd (ti hadt)) (snd (ti ladt));
          AT_re: AT hadt = AT ladt;
          nps_re: nps hadt = nps ladt;
          init_re: init hadt = init ladt;

          buffer_re: buffer hadt = buffer ladt;

          com1_re: com1 hadt = com1 ladt;
          console_re: console hadt = console ladt;
          console_concrete_re: console_concrete hadt = console_concrete ladt;
          ioapic_re: ioapic ladt = ioapic hadt;
          lapic_re: lapic ladt = lapic hadt;
          intr_flag_re: intr_flag ladt = intr_flag hadt;
          curr_intr_num_re: curr_intr_num ladt = curr_intr_num hadt;
          drv_serial_re: drv_serial hadt = drv_serial ladt;
          in_intr_re: in_intr hadt = in_intr ladt;
          tf_re: tf hadt = tf ladt;
          tf_reg_re: tf_reg hadt = tf_reg ladt;

          CPU_ID_re: CPU_ID hadt = CPU_ID ladt;
          cid_re: cid hadt = cid ladt;
          multi_oracle_re: multi_oracle hadt = multi_oracle ladt;
          multi_log_re: multi_log hadt = multi_log ladt;
          lock_re: lock hadt = lock ladt
        }.

    Inductive match_RData: stencil → HDATA → mem → meminj → Prop :=
    | MATCH_RDATA: ∀ habd m f s, match_RData s habd m f.

    Local Hint Resolve MATCH_RDATA.

    Global Instance rel_ops: CompatRelOps HDATAOps LDATAOps :=
      {
        relate_AbData s f d1 d2 := relate_RData f d1 d2;
        match_AbData s d1 m f := match_RData s d1 m f;
        new_glbl := nil
      }.

Properties of relations

    Section Rel_Property.

Prove that after taking one step, the refinement relation still holds
      Lemma relate_incr:
        ∀ abd abd´ f f´,
          relate_RData f abd abd´
          → inject_incr f f´
          → relate_RData f´ abd abd´.
      Proof.
        inversion 1; subst; intros; inv H; constructor; eauto.
      Qed.

      Global Instance rel_prf: CompatRel HDATAOps LDATAOps.
      Proof.
        constructor; intros; simpl; trivial.
        eapply relate_incr; eauto.
      Qed.

    End Rel_Property.

Proofs the one-step forward simulations for the low level specifications

    Section OneStep_Forward_Relation.

      Lemma serial_intr_handler_asm_exists:
        ∀ s habd habd´ labd rs rs´ f,
          serial_intr_handler_asm_spec rs habd = Some (habd´, rs´) →
          relate_AbData s f habd labd →
          ∃ labd´, serial_intr_handler_asm_spec rs labd
                        = Some (labd´, rs´) ∧ relate_AbData s f habd´ labd´.
      Proof.
        unfold serial_intr_handler_asm_spec; intros.
        exploit relate_impl_iflags_eq; eauto; inversion 1.
        exploit relate_impl_in_intr_eq; eauto; inversion 1.
        exploit relate_impl_intr_flag_eq; eauto; inversion 1.
        exploit relate_impl_init_eq; eauto; inversion 1.
        exploit relate_impl_ioapic_eq; eauto; inversion 1.
        exploit relate_impl_console_eq; eauto; inversion 1.
        exploit relate_impl_curr_intr_num_eq; eauto; inversion 1.
        exploit relate_impl_tf´_eq; eauto; inversion 1.
        intros.
        revert H. subrewrite.
        subdestruct; inv HQ.
        exploit (lapic_eoi_exist s _ _ (((ObjX86.save_context_spec rs labd) { ioapic
                                                                              : (ioapic labd) { s / IoApicEnables [4]:false}}) { intr_flag
                                                                                                                                    : true}) f Hdestruct3); eauto.
        apply relate_impl_intr_flag_update; eauto.
        rewrite H10.
        apply relate_impl_ioapic_update; eauto.
        unfold ObjX86.save_context_spec.
        rewrite H11, H13.
        apply relate_impl_tf´_update; eauto.
        intros (labd´ & HP´ & HM´).
        rewrite HP´.
        exploit (cons_intr_aux_exist s _ _ labd´ f Hdestruct4); eauto.
        intros (labd´´ & HP´´ & HM´´).
        rewrite HP´´.
        inversion HM´.
        inversion HM´´.
        subst.
        functional inversion Hdestruct5; subst.
        unfold restore_context_spec.
        simpl in ×.
        rewrite <- tf_re1.
        rewrite H15.
        esplit.
        split.
        reflexivity.
        generalize relate_impl_ioapic_update; intro.
        simpl in H.
        rewrite ioapic_re1.
        eapply H; eauto.
        unfold restore_context_spec.
        simpl in ×.
        rewrite <- tf_re1.
        rewrite H15.
        esplit.
        split.
        reflexivity.
        generalize relate_impl_tf´_update; intro.
        simpl in H.
        eapply H; eauto.
        generalize relate_impl_ioapic_update; intro.
        simpl in H17.
        rewrite ioapic_re1.
        eapply H17; eauto.
      Qed.

      Lemma serial_intr_handler_sw_to_asm:
        ∀ d1 d2 rs,
          high_level_invariant d1 →
          serial_intr_handler_sw_spec d1 = Some d2 →
          serial_intr_handler_asm_spec rs d1 = Some (d2, rs).
      Proof.
        intros d1 d2 rs Hinv H. inversion Hinv.
        apply ObjX86Proof.serial_intr_handler_sw_to_asm; auto 1.
      Qed.

      Section PASSTHROUGH_RPIM.

        Global Instance: (LoadStoreProp (hflatmem_store:= flatmem_store´) (lflatmem_store:= flatmem_store´)).
        Proof.
          accessor_prop_tac.
          - eapply flatmem_store´_exists; eauto.
        Qed.

        Lemma passthrough_correct:
          sim (crel HDATA LDATA) dhandlercxt dhandlerasm.
        Proof.
          sim_oplus.
          - apply fload´_sim.
          - apply fstore´_sim.
          - apply page_copy´_sim.
          - apply page_copy_back´_sim.

          - apply vmxinfo_get_sim.
          - apply setPG_sim.
          - apply setCR3_sim.
          - apply get_size_sim.
          - apply is_mm_usable_sim.
          - apply get_mm_s_sim.
          - apply get_mm_l_sim.
          - apply get_CPU_ID_sim.
          - apply get_curid_sim.
          - apply set_curid_sim.
          - apply set_curid_init_sim.

          - apply (release_lock_sim (valid_arg_imply:= Shared2ID0_imply)).
          -
            eapply acquire_lock_sim0; eauto.
            intros. inv H; trivial; try inv H0.
          - apply ticket_lock_init0_sim.
          - apply serial_irq_check_sim.
          - apply iret_sim.
          - apply cli_sim.
          - apply sti_sim.
          - apply serial_irq_current_sim.
          - apply ic_intr_sim.
          - apply ioapic_mask_sim.
          - apply ioapic_unmask_sim.
          - layer_sim_simpl. compatsim_simpl (@match_AbData). intros.
            exploit serial_intr_handler_asm_exists; eauto 1. inversion Hhigh´.
            eapply serial_intr_handler_sw_to_asm; eauto.
            intros [labd´ [r´0 ?]].
            match_external_states_simpl.
            + eassumption.
            + inv ASM_INV.
              inv inv_inject_neutral.
              apply inv_reg_inject_neutral.
            + intros.
              inv ASM_INV.
              unfold AsmX.wt_regset in inv_reg_wt.
              destruct r; simpl in *; eauto.
          - apply serial_putc_sim.
          - apply serial_hw_intr_sim.
          - apply cons_buf_read_sim.
          - apply trapin_sim.
          - apply trapout´_sim.
          - apply hostin_sim.
          - apply hostout´_sim.
          - apply proc_create_postinit_sim.
          - apply trap_info_get_sim.
          - apply trap_info_ret_sim.
          - layer_sim_simpl.
            + eapply load_correct1.
            + eapply store_correct1.
        Qed.

      End PASSTHROUGH_RPIM.

    End OneStep_Forward_Relation.

  End WITHMEM.

End Refinement.