Require Import Coqlib.
Require Import Maps.
Require Import ASTExtra.
Require Import Integers.
Require Import Floats.
Require Import Values.
Require Import Memory.
Require Import Events.
Require Import Stacklayout.
Require Import Globalenvs.
Require Import AsmX.
Require Import Smallstep.
Require Import AuxStateDataType.
Require Import Constant.
Require Import GlobIdent.
Require Import FlatMemory.
Require Import CommonTactic.
Require Import AuxLemma.
Require Import RealParams.
Require Import PrimSemantics.
Require Import LAsm.
Require Import LoadStoreSem1.

Require Import liblayers.logic.PTreeModules.
Require Import liblayers.logic.LayerLogicImpl.
Require Import liblayers.compat.CompatLayers.
Require Import liblayers.compat.CompatGenSem.
Require Import LayerCalculusLemma.

Require Import FutureTactic.

Require Import INVLemmaContainer.
Require Import INVLemmaQLock.
Require Import INVLemmaInterrupt.
Require Import INVLemmaDriver.

Require Import AbstractDataType.
Require Import DeviceStateDataType.

Require Export ObjCPU.
Require Export ObjMM.
Require Export ObjFlatMem.
Require Export ObjContainer.
Require Export ObjMultiprocessor.
Require Export ObjQLock.
Require Export ObjPMM.

Require Export ObjInterruptManagement.
Require Export ObjInterruptController.
Require Export ObjConsole.
Require Export ObjSerialDriver.

Section WITHMEM.

  Local Open Scope Z_scope.
  Context `{real_params: RealParams}.
  Context `{oracle_prop: MultiOracleProp}.

  Record high_level_invariant (abd: RData) :=
    mkInvariant {
        CPU_ID_range: 0 ≤ (CPU_ID abd) < TOTAL_CPU;
        valid_curid: 0 ≤ ZMap.get (CPU_ID abd) (cid abd) < num_proc;
        valid_multi_oracle_pool_inv: valid_multi_oracle_pool_H (multi_oracle abd);
        valid_hlock_pool_inv: valid_hlock_pool (multi_log abd);
        valid_kern: ikern abd = false → pg abd = true ∧ init abd = true;
        valid_mm: init abd = true → MM_valid (MM abd) (MMSize abd);
        correct_mm: init abd = true → MM_correct (MM abd) (MMSize abd);
        valid_mm_kern: init abd = true → MM_kern (MM abd) (MMSize abd);
        valid_mm_size: init abd = true → 0 < MMSize abd ≤ Int.max_unsigned;
        valid_CR3: pg abd = true → CR3_valid (CR3 abd);
        valid_ihost: ihost abd = false → pg abd = true ∧ init abd = true ∧ ikern abd = true;
        valid_container: Container_valid (AC abd);

        valid_cons_buf_rpos: 0 ≤ rpos (console abd) < CONSOLE_BUFFER_SIZE;
        valid_cons_buf_length: 0 ≤ Zlength (cons_buf (console abd)) < CONSOLE_BUFFER_SIZE
      }.

  Global Instance malinit_data_ops : CompatDataOps RData :=
    {
      empty_data := init_adt multi_oracle_init2;
      high_level_invariant := high_level_invariant;
      low_level_invariant := low_level_invariant;
      kernel_mode adt := ikern adt = true ∧ ihost adt = true
    }.

  Section Property_Abstract_Data.

    Lemma empty_data_high_level_invariant:
      high_level_invariant (init_adt multi_oracle_init2).
    Proof.
      constructor; auto; simpl; try discriminate 1.
      - apply current_CPU_ID_range.
      - rewrite ZMap.gi; intuition.
      - apply valid_ticket_oracle2.
      - apply valid_hlock_pool_init.
      -
        apply empty_container_valid.
    Qed.

    Global Instance malinit_data_prf : CompatData RData.
    Proof.
      constructor.
      - apply low_level_invariant_incr.
      - apply empty_data_low_level_invariant.
      - apply empty_data_high_level_invariant.
    Qed.

  End Property_Abstract_Data.

  Context `{Hstencil: Stencil}.
  Context `{Hmem: Mem.MemoryModelX}.
  Context `{Hmwd: UseMemWithData mem}.

  Section INV.

    Global Instance acquire_lock_inv: AcquireInvariants acquire_lock_spec1.
    Proof.
      constructor; unfold acquire_lock_spec; intros; subdestruct;
      inv H; inv H0; constructor; auto; simpl; intros.
      - eapply valid_hlock_pool_gss´; eauto.
    Qed.

    Global Instance release_lock_inv: ReleaseInvariants release_lock_spec1.
    Proof.
      constructor; unfold release_lock_spec; intros; subdestruct;
      inv H; inv H0; constructor; auto; simpl; intros.
      - eapply valid_hlock_pool_gss´; eauto.
    Qed.


    Global Instance acquire_lock_AT_inv: PreservesInvariants acquire_lock_AT_spec.
    Proof.
      preserves_invariants_simpl_auto1.
      - eapply valid_hlock_pool_gss´; eauto.
      - eapply valid_hlock_pool_gss´; eauto.
    Qed.

    Global Instance release_lock_AT_inv: PreservesInvariants release_lock_AT_spec.
    Proof.
      preserves_invariants_simpl_auto1.
      - eapply valid_hlock_pool_gss´; eauto.
    Qed.

    Global Instance set_curid_inv: PreservesInvariants set_curid_spec.
    Proof.
      preserves_invariants_simpl_auto; eauto 2.
      - rewrite ZMap.gss. auto.
    Qed.

    Global Instance set_curid_init_inv: PreservesInvariants set_curid_init_spec.
    Proof.
      preserves_invariants_simpl_auto; eauto 2.
      case_eq (zeq (CPU_ID d) (Int.unsigned i)); intros; subst.
      - rewrite e; rewrite ZMap.gss; omega.
      - rewrite ZMap.gso; auto.
    Qed.

    Global Instance setPG_inv: PreservesInvariants setPG0_spec.
    Proof.
      preserves_invariants_simpl_auto.
    Qed.

    Global Instance set_nps_inv: PreservesInvariants set_nps_spec.
    Proof.
      preserves_invariants_simpl_auto.
    Qed.

    Global Instance set_at_u_inv: PreservesInvariants set_at_u_spec.
    Proof.
      preserves_invariants_simpl_auto.
    Qed.

    Global Instance set_at_norm_inv: PreservesInvariants set_at_norm_spec.
    Proof.
      preserves_invariants_simpl_auto.
    Qed.

    Global Instance set_at_c_inv: PreservesInvariants set_at_c_spec.
    Proof.
      preserves_invariants_simpl_auto.
    Qed.

    Global Instance setCR3_inv: SetCR3Invariants setCR30_spec.
    Proof.
      constructor; intros; functional inversion H; eauto.
      - inv H0; constructor; trivial.
      - inv H0; constructor; auto.
    Qed.

    Global Instance container_init_inv: PreservesInvariants container_init_spec.
    Proof.
      preserves_invariants_simpl low_level_invariant high_level_invariant.
      - assumption.
      - eapply real_valid_hlock_pool; eauto.
      - apply real_valid_mm.
      - apply real_correct_mm.
      - apply real_valid_mm_kern.
      - apply real_valid_mm_size.
      - apply AC_init_container_valid.
    Qed.

    Global Instance container_split_inv: PreservesInvariants container_split_spec.
    Proof.
      preserves_invariants_simpl_auto.
      - rewrite <- H1 in H0.
        exploit split_container_valid; eauto.
    Qed.

    Global Instance container_alloc_inv: PreservesInvariants container_alloc_spec.
    Proof.
      preserves_invariants_simpl_auto.
      exploit alloc_container_valid; eauto.
    Qed.

    Global Instance trapin_inv: PrimInvariants trapin_spec.
    Proof.
      PrimInvariants_simpl_auto.
    Qed.

    Global Instance trapout_inv: PrimInvariants trapout0_spec.
    Proof.
      PrimInvariants_simpl_auto.
    Qed.

    Global Instance hostin_inv: PrimInvariants hostin_spec.
    Proof.
      PrimInvariants_simpl_auto.
    Qed.

    Global Instance hostout_inv: PrimInvariants hostout_spec.
    Proof.
      PrimInvariants_simpl_auto.
    Qed.

    Global Instance fstore_inv: PreservesInvariants fstore´_spec.
    Proof.
      preserves_invariants_simpl_auto.
    Qed.


    Global Instance page_copy_inv: PreservesInvariants page_copy´_spec.
    Proof.
      preserves_invariants_simpl_auto.
      - eapply valid_hlock_pool_gss´; eauto.
    Qed.

    Global Instance page_copy_back_inv: PreservesInvariants page_copy_back´_spec.
    Proof.
      preserves_invariants_simpl_auto.
    Qed.

    Global Instance cli_inv: PreservesInvariants cli_spec.
    Proof.
      preserves_invariants_direct low_level_invariant high_level_invariant; eauto 2.
    Qed.

    Global Instance sti_inv: PreservesInvariants sti_spec.
    Proof.
      preserves_invariants_direct low_level_invariant high_level_invariant; eauto 2.
    Qed.

    Global Instance cons_buf_read_inv:
      PreservesInvariants cons_buf_read_spec.
    Proof.
      preserves_invariants_nested low_level_invariant high_level_invariant; eauto 2.
    Qed.

    Global Instance serial_putc_inv:
      PreservesInvariants serial_putc_spec.
    Proof.
      preserves_invariants_simpl low_level_invariant high_level_invariant; eauto 2.
    Qed.

    Global Instance serial_intr_disable_inv: PreservesInvariants serial_intr_disable_spec.
    Proof.
      constructor; simpl; intros; inv_generic_sem H.
      - inversion H0; econstructor; eauto 2 with serial_intr_disable_invariantdb.
        generalize (serial_intr_disable_preserves_tf _ _ H2); intro tmprw; rewrite <- tmprw; assumption.
      - inversion H0; econstructor; eauto 2 with serial_intr_disable_invariantdb.
      - eauto 2 with serial_intr_disable_invariantdb.
   Qed.

    Global Instance serial_intr_enable_inv:
      PreservesInvariants serial_intr_enable_spec.
    Proof.
      constructor; simpl; intros; inv_generic_sem H.
      - inversion H0; econstructor; eauto 2 with serial_intr_enable_invariantdb.
        generalize (serial_intr_enable_preserves_tf _ _ H2); intro tmprw; rewrite <- tmprw; assumption.
      - inversion H0; econstructor; eauto 2 with serial_intr_enable_invariantdb.
      - eauto 2 with serial_intr_enable_invariantdb.
    Qed.

    Global Instance proc_create_postinit_inv:
      PreservesInvariants proc_create_postinit_spec.
    Proof.
      preserves_invariants_simpl low_level_invariant high_level_invariant; eauto 2.
    Qed.

  End INV.

  Require Import LoadStoreSem1.

  Definition exec_loadex {F V} := exec_loadex1 (F := F) (V := V).

  Definition exec_storeex {F V} := exec_storeex1 (flatmem_store:= flatmem_store´) (F := F) (V := V).

  Global Instance flatmem_store_inv: FlatmemStoreInvariant (flatmem_store:= flatmem_store´).
  Proof.
    split; inversion 1; intros.
    - functional inversion H0; constructor; auto.
    - functional inversion H1; constructor; auto.
  Qed.

  Global Instance trapinfo_set_inv: TrapinfoSetInvariant.
  Proof.
    split; inversion 1; intros; constructor; auto.
  Qed.

  Definition malinit_fresh: compatlayer (cdata RData) :=
    (at_get ↦ gensem get_at_u_spec
            ⊕ is_norm ↦ gensem is_at_norm_spec
            ⊕ at_get_c ↦ gensem get_at_c_spec
            ⊕ at_set ↦ gensem set_at_u_spec
            ⊕ set_norm ↦ gensem set_at_norm_spec
            ⊕ at_set_c ↦ gensem set_at_c_spec
            ⊕ set_nps ↦ gensem set_nps_spec
            ⊕ get_nps ↦ gensem get_nps_spec)
            ⊕ acquire_lock_AT ↦ gensem acquire_lock_AT_spec
            ⊕ release_lock_AT ↦ gensem release_lock_AT_spec.

  Definition malinit_passthrough: compatlayer (cdata RData) :=
    fload ↦ gensem fload´_spec
          ⊕ fstore ↦ gensem fstore´_spec
          
          ⊕ page_copy ↦ gensem page_copy´_spec
          ⊕ page_copy_back ↦ gensem page_copy_back´_spec

          ⊕ vmxinfo_get ↦ gensem vmxinfo_get_spec
          ⊕ get_size ↦ gensem MMSize
          ⊕ is_usable ↦ gensem is_mm_usable_spec
          ⊕ get_mms ↦ gensem get_mm_s_spec
          ⊕ get_mml ↦ gensem get_mm_l_spec
          ⊕ set_pg ↦ gensem setPG0_spec
          ⊕ set_cr3 ↦ setCR3_compatsem setCR30_spec
          ⊕ container_init ↦ gensem container_init_spec
          ⊕ container_get_parent ↦ gensem container_get_parent_spec
          ⊕ container_get_nchildren ↦ gensem container_get_nchildren_spec
          ⊕ container_get_quota ↦ gensem container_get_quota_spec
          ⊕ container_get_usage ↦ gensem container_get_usage_spec
          ⊕ container_can_consume ↦ gensem container_can_consume_spec
          ⊕ container_split ↦ gensem container_split_spec
          ⊕ container_alloc ↦ gensem container_alloc_spec
          ⊕ get_CPU_ID ↦ gensem get_CPU_ID_spec
          ⊕ get_curid ↦ gensem get_curid_spec
          ⊕ set_curid ↦ gensem set_curid_spec
          ⊕ set_curid_init ↦ gensem set_curid_init_spec
 
          ⊕ release_lock ↦ primcall_release_lock_compatsem release_lock release_lock_spec1
          ⊕ acquire_lock ↦ primcall_acquire_lock_compatsem acquire_lock_spec1
          

          ⊕ cli ↦ gensem cli_spec
          ⊕ sti ↦ gensem sti_spec
          ⊕ serial_intr_disable ↦ gensem serial_intr_disable_spec
          ⊕ serial_intr_enable ↦ gensem serial_intr_enable_spec
          ⊕ serial_putc ↦ gensem serial_putc_spec
          ⊕ cons_buf_read ↦ gensem cons_buf_read_spec
          ⊕ trap_in ↦ primcall_general_compatsem trapin_spec
          ⊕ trap_out ↦ primcall_general_compatsem trapout0_spec
          ⊕ host_in ↦ primcall_general_compatsem hostin_spec
          ⊕ host_out ↦ primcall_general_compatsem hostout_spec
          ⊕ proc_create_postinit ↦ gensem proc_create_postinit_spec
          ⊕ trap_get ↦ primcall_trap_info_get_compatsem trap_info_get_spec
          ⊕ trap_set ↦ primcall_trap_info_ret_compatsem trap_info_ret_spec
          ⊕ accessors ↦ {| exec_load := @exec_loadex; exec_store := @exec_storeex |}.

  Definition malinit : compatlayer (cdata RData) := malinit_fresh ⊕ malinit_passthrough.

End WITHMEM.